以下是文华论坛编写的止损案例,本人觉得实在太经典了,是精华.
各位宽客可以根据实际情况制定自己的止损策略.
以下是常见的几种止损案例编写，
G1：定额止盈止损
G2：动态追踪止赢止损
G3：保本单止赢策略
G4: 定额止盈止损+定时止损(尾盘清仓)
G5: 子账户权益回撤止赢止损
G6: 关键点位止赢止损
G7: 阶梯止损
G8: ATR止损
G9: SAR止损
G10:吊灯止损与+YOYO止损
固定额度止盈止损是最常用且高效的止盈止损方式，并且可以将额度作为参数针对不同品种进行参数优化，得出最贴合品种波动性的止损止赢价差。
策略原理：
①做多固定下跌N跳止损，固定上涨M跳止盈
做空固定上涨N跳止损，固定下跌M跳止盈
②做多固定下跌N%止损，固定上涨M%止盈
做空固定上涨N%止损，固定下跌M%止盈
策略及源码：
①
(C<=BKPRICE-N*MINPRICE)||(C>=BKPRICE+M*MINPRICE),SP;
(C>=SKPRICE+N*MINPRICE)||(C<=SKPRICE-M*MINPRICE),BP;
②
(C<=BKPRICE*(1-N/100))||(C>=BKPRICE*(1+M/100)),SP;
(C>=SKPRICE*(1+N/100))||(C<=SKPRICE*(1-M/100)),BP;
G2：动态追踪止赢止损
损价位会随着盈利的增加而变化，这种方法可以最大程度实现”让盈利奔跑”。做多开仓，设置跟踪止损后的最高价每上涨一个价位，止损平仓价就跟着上涨一个价位，当价格从回撤了设置的止损价差时，触发止损。
策略及原理：
①以开仓后最高价为基础，回撤N跳止损
②以开仓后最高价为基础，回撤N%止损
③当盈利超过M点后启用N点的动态止盈，否则以P点定额止损
策略源码：
①
C<BKHIGH-N*MINPRICE,SP;
C>SKLOW+N*MINPRICE,BP;
②
C<BKHIGH*(1-N/100),SP;
C>SKLOW*(1+N/100),BP;
③
BKHIGH>BKPRICE+M*MINPRICE&&C<BKHIGH-N*MINPRICE,SP;
C<=BKPRICE-P*MINPRICE,SP;
SKLOW<SKPRICE-M*MINPRICE&&C>SKLOW+N*MINPRICE,BP;
C>=SKPRICE+P*MINPRICE,BP;
G3：保本单止赢策略
做多开仓后，在”开仓均价+设置的保本价差”位置产生了一条保本线，最新价超过设置的保本止损线后，再回落到这个保本止损线时才触发止损。这是一种现代人的止损思想——盈利状态下止损，目的是保住赚到的利润。
策略及原理：
在开仓+N跳设置一条保本线，开仓价格超过“开仓价+N跳”再回落到此价位止赢
注：建议配合其他止赢止损方式，避免反向变动导致保本单无法触发
策略源码：
BKHIGH>BKPRICE+N*MINPRICE && C<=BKPRICE+N*MINPRICE,SP;
SKLOW<SKPRICE-N*MINPRICE && C>=SKPRICE-N*MINPRICE,BP;
G4：定额止盈止损+定时止损(尾盘清仓)
期货是全球市场，内盘休市的时候外盘合约还在交易，收盘后潜在的利空因素会导致开盘价跳空，对应日内交易者而言尾盘清仓可以规避这种风险
策略及原理：
① 小周期上每一交易日收盘前5分钟清仓
②小周期上夜盘、上午及白盘收盘前5分钟清仓
策略源码：
①
A&&CLOSEMINUTE1>5,BK;
B&&CLOSEMINUTE1>5,SK;//其中AB为开仓条件，注意限制尾盘不开仓
CLOSEMINUTE1<=5,CLOSEOUT;
CHECKSIG(CLOSEOUT,’A’,0,’C’,0,0);//满足条件立即执行
②
TT:=CLOSEMINUTEEVERY1(1)<=5||CLOSEMINUTEEVERY1(3)<=5||CLOSEMINUTEEVERY1(4)<=5;
//判断距离夜盘或者午盘以及白盘收盘时间小于5分钟
NOT(TT)&&A,BK;
NOT(TT)&&B,SK;//其中AB为开仓条件，注意限制尾盘不开仓
TT,CLOSEOUT;
CECKSIG(CLOSEOUT,’A’,0,’C’,0,0);
G5：子账户权益回撤止赢止损
仓位管理和风险控制是资金管理的重中之重，通过调用策略的盈亏和资金变化，可以根绝模组子账户的权益变动进行止盈止损。
策略及原理：
①当前权益回撤超过初始权益的N%进行清仓
②当前权益回测超过开仓时权益的N%进行清仓
策略源码：
①
QC:MONEYTOT<INITMONEY(1-N/100);
QC,CLOSEOUT;
②
NN:BARSLAST(BKVOL+SKVOL>REF(BKVOL+SKVOL,1));//初次开仓到现在的k线周期数
QC:MONEYTOT<REF(MONEYTOT,NN)*(1-N/100);//当前权益回撤到开仓时权益的N%以下
QC,CLOSEOUT;
G6：关键点止赢止损
关键点位止赢止损是技术分析中最常用的方式，突破支撑与压力位说明行情已经反转应该及时止盈止损，,可以将这种止盈止损思想融入到量化交易中。
策略及原理：
①以昨日最高价与最低价为今日止损条件
②以前N周期内高点与低点为止损条件
策略源码：
①
H1:REF(HHV(H,DAYBARPOS),DAYBARPOS);//昨日最高价
L1:REF(LLV(L,DAYBARPOS),DAYBARPOS);//昨日最低价
C>H1,BP;//突破昨日高点平空
C<L1,SP;//突破昨日高点平多
AUTOFILTER;
②
H1:HV(H,N);//前N周期内最高价
L1:LV(L,N);//前N周期内最低价
C>H1,BP;//突破H1平空
C<L1,SP;//突破L1平多
AUTOFILTER;
G7：阶梯止损
与动态止损相类似，阶梯止损策略不对止盈止损价格进行预判，而是随着行情变动不断调整，在保证一定亏损额度的情况下，可以实现利润的最大化。
策略及原理：
以开仓价为基础，开仓时以M点为固定价差止损，当行情每朝着有利方向变动N点，止损价格也提高P点。
举例：初始止损价差M为10，N为20,P为5，以100元开仓做到初始止损价90元，当行情涨到120元时，止损价提高到95元，依次类推。
策略源码：
C<BKPRICE-M*MINPRICE+INTPART((BKHIGH-BKPRICE)/(N*MINPRICE))*P,SP;
C>SKPRICE+M*MINPRICE-INTPART((SKPRICE-SKLOW)/(N*MINPRICE))*P,BP;
G8：ATR止损
ATR平均真实波动范围，简称ATR指标，可以用来衡量市场波动的强烈度，即为了显示市场变化率的指标。通过平均真实波动数值可以为止盈止损策略提供参考，当短期价格偏离平均波动负的时就有回调的可能。
策略及原理：
以开仓价为基础，上涨超过开仓价+开仓时2.5倍ATR为止赢条件，下跌超过开仓价-开仓时1.5倍ATR为止损条件
策略源码：
TR : MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
//求最高价减去最低价，一个周期前的收盘价减去最高价的绝对值，一个周期前的收盘价减去最低价的绝对值，这三个值中的最大值
ATR : MA(TR,26),COLORYELLOW;//求26个周期内的TR的简单移动平均
C>BKPRICE+2.5*REF(ATR,BARSBK)||C<BKPRICE-1.5*REF(ATR,BARSBK),SP;
C<SKPRICE-2.5*REF(ATR,BARSSK)||C>SKPRICE+1.5*REF(ATR,BARSSK),BP;
AUTOFILTER;
G9：SAR止损
SAR指标又叫抛物线指标或停损转向操作点指标，是最经典的止盈止损点技术分析指标，属于时间与价格并重的系统。它是通过对价格振幅及时间的分析研究,随时设立停损点以观察股票卖出时机的一种技术指标。
策略及原理：
当SAR指标反转由红转青色时平多仓，当SAR指标反转由青转红色时平空仓
策略源码：
N:=4;
STEP:=2;
MVALUE:=20;
STEP1:=STEP/100;
MVALUE1:=MVALUE/100;
SARLINE:SAR(N,STEP1,MVALUE1),CIRCLEDOT,NODRAW;
SARS:IF(SARLINE>0,SARLINE,NULL),CIRCLEDOT,COLORRED;
SARX:IF(SARLINE<0,ABS(SARLINE),NULL),CIRCLEDOT,COLORCYAN;//在主图输出SAR指标园点
CROSS(SARLINE,0),BP;
CROSSDOWN(SARLINE,0),SP;
AUTOFILTER;
G10：吊灯止损与+YOYO止损
吊灯止损以买开仓后的最高价和卖开仓后的最低价为基准价，根据ATR确定价差，止损的时间点是在最新价与基准价的关系满足价差条件的时候。在趋势跟踪系统中吊灯止损策略应用的比较多。
YOYO止损以前一根K线的收盘价是基准价，根据ATR确定价差，止损的时间点是最新价与基准价的关系满足价差条件的时候。
策略及原理：
吊灯止损部分基准取开仓后的极值，以3倍ATR止损
YOYO部分以前一根K线的收盘价为前者的基准价，以1.5倍ATR止损
策略源码：
TR:=MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR:=MA(TR,N);
//吊灯止损部分
BKHIGH-BKPRICE>2*ATR && BKHIGH-C>3*ATR,SP;
SKPRICE-SKLOW>2*ATR && C-SKLOW>3*ATR,BP;
//YOYO止损部分
REF(C,1)-C>1.5*ATR,SP;
C-REF(C,1)>1.5*ATR,BP;
评论0